如何根据一列中的变量将Excel工作表拆分为选项卡

使用 Excel 时,您可能希望将工作表分成不同的几个选项卡(或工作表)。有不同的方法可以将它们分开。

例如,如果列中只有几个变量,并且这是一次工作,则可以使用“ 移动和复制 ' 命令先有几个工作表,然后在一个工作表中保留一个变量。但是,如果您有很多变量或不断重复这种工作,请使用 micro 的步骤如下:

第 1 步:按快捷键“ Alt + F11 ' 打开 Microsoft Visual Basic for Applications 窗口;

或者,请点击“ 开发商 ' 功能区中的选项卡,然后单击 ' 视觉基础 '打开窗户。

第二步:在新窗口中,点击“ 插入 ' 功能区中的选项卡,然后单击 ' 模块 ';

第 3 步:将以下代码复制并粘贴到模块窗口中;

Sub parse_data()
    Dim lr As Long
    Dim ws As Worksheet
    Dim vcol, i As Integer
    Dim icol As Long
    Dim myarr As Variant
    Dim title As String
    Dim titlerow As Integer
    Application.ScreenUpdating = False
    vcol = Application.InputBox(prompt:="Which column would you like to filter by?", title:="Filter column", Default:="1", Type:=1)
    Set ws = ActiveSheet
    lr = ws.Cells(ws.Rows.Count, vcol).End(xlUp).Row
    title = "A1"
    titlerow = ws.Range(title).Cells(1).Row
    icol = ws.Columns.Count
    ws.Cells(1, icol) = "Unique"
    For i = 2 To lr
        On Error Resume Next
        If ws.Cells(i, vcol) <> "" And Application.WorksheetFunction.Match(ws.Cells(i, vcol), ws.Columns(icol), 0) = 0 Then
            ws.Cells(ws.Rows.Count, icol).End(xlUp).Offset(1) = ws.Cells(i, vcol)
        End If
    Next
    myarr = Application.WorksheetFunction.Transpose(ws.Columns(icol).SpecialCells(xlCellTypeConstants))
    ws.Columns(icol).Clear
    For i = 2 To UBound(myarr)
        ws.Range(title).AutoFilter field:=vcol, Criteria1:=myarr(i) & ""
        If Not Evaluate("=ISREF('" & myarr(i) & "'!A1)") Then
            Sheets.Add(after:=Worksheets(Worksheets.Count)).Name = myarr(i) & ""
        Else
            Sheets(myarr(i) & "").Move after:=Worksheets(Worksheets.Count)
        End If
        ws.Range("A" & titlerow & ":A" & lr).EntireRow.Copy Sheets(myarr(i) & "").Range("A1")
        'Sheets(myarr(i) & "").Columns.AutoFit
    Next
    ws.AutoFilterMode = False
    ws.Activate
    Application.ScreenUpdating = True
End Sub

第四步:点击“ 运行子 ' 按钮(或按 F5 键)运行代码;

第五步:在弹出框中输入列号,例如1,工作表将根据列中的变量进行拆分;

第6步:之后会出现新的标签。

如果您想进一步将每个选项卡拆分为单独的文件,请参阅 到这里的帖子 .